Quand il y a plusieurs fichiers .csv

Précédemment, nous avons créé un rapport de publipostage où il n’y avait qu’un seul fichier de données .csv de généré lors du lancement du rapport dans EMu. Bien qu’il soit possible dans beaucoup de cas d’inclure toutes les données dans un seul fichier .csv, il y a des circonstances pour lesquelles plus d’un fichier .csv est généré quand un rapport est lancé dans EMu : par exemple, les champs qui sont à la fois un champ joint ET un tableau de valeurs (voir notre rapport créé comme exemple pour un exemple de ces champs) seront toujours exportés depuis EMu dans un fichier de données .csv séparé quand un rapport est lancé.

Note: Cet exemple étend le rapport développé précédemment pour un seul fichier .csv. Notez que le code Visual Basic ajouté pour nous connecter au bon DSN est nécessaire, même si nous travaillons avec un seul ou plusieurs fichiers .csv.

1 : Éditer un document de rapport principal dans Word

Note: Si vous n'avez pas commenté MainDocument.Close SaveChanges:=False dans le code VB, faites-le maintenant afin de pouvoir faire un test. Des détails peuvent être trouvés dans 1. Écrire le code VB (Étape 9).

Dans notre exemple précédent nous avons créé le rapport de publipostage suivant, en extrayant les données depuis un seul fichier .csv appelé eloans.csv, qui contient les informations de Personnes / Organisations et Prêts/Emprunts :

Code

Dans 1. Écrire le code VB nous avons établit une connexion entre notre rapport de publipostage et la principale source de données, eloans.csv. Toutes les données affichées dans le rapport ci-dessus sont extraites de ce fichier .csv, et contiennent les détails sur le prêt et l’emprunteur.

Cependant, nous voulons également inclure des détails sur les objets prêtés, mais ces données ne se trouvent pas dans eloans.csv ; elles sont extraites d'un champ appelé Objet : (Objet prêté), qui est un champ annexe et une table de valeurs. Comme nous l'avons vu, les valeurs d'un champ qui est à la fois un champ joint ET une table de valeurs seront toujours exportées dans un fichier .csv séparé. Afin d'inclure les données de ce deuxième (troisième, n-ième) fichier .csv, nous devons ajouter du code Visual Basic à notre rapport de publipostage.

Pour éditer le document de rapport principal dans Word :

Ouvrir le document de rapport principal (Prêts_Emprunts.doc dans cet exemple) et activer les macros quand c’est nécessaire.
Si nécessaire, sélectionner ALT+F9 pour afficher les codes de champ :
Nous allons inclure les détails sur l'objet dans une table. Placez le curseur à l'endroit où la table doit s'afficher :
Pour cet exemple, nous allons insérer un tableau à deux cellules sur une seule ligne :
Avec le curseur dans la première cellule, cliquez sur Insérer des champs Fusionner dans la barre d'outils Publipostage.
Note: Si la Barre d'outils de Publipostage ne s'affiche pas, sélectionner Affichage>Barres d'outils>Publipostage dans la barre de menu de MS Word.
La boîte de dialogue Insérer un champ de fusion s'affiche.
Sélectionner le champ clé qui lie le fichier .csv principal (eloans.csv dans cet exemple) et le tableau joint duquel nous souhaitons extraire les données (ObjObjec.csv dans cet exemple). Dans cet exemple, nous sélectionnons eloans_key :
Voir Étape 1 : Créer un rapport dans EMu pour les détails sur quels fichiers .csv sont générés dans cet exemple.
Sélectionner Insérer et ensuite fermer la boîte Insérer un champ de fusion :
Assurez-vous que la police de caractères de ce tableau correspond à la police du reste du texte dans votre document.

Ensuite nous devons ajouter le code Visual Basic.

[Fermer]

2: Écrire le code VB

Sélectionnez Outils>Macro>Éditeur Visual Basic (ALT+F11) dans la barre de menu.
L'éditeur Microsoft Visual Basic s'ouvre :

Dans cet exemple, nous saisissons le code suivant immédiatement après le code qui connecte notre rapport de publipostage à la source de données principale.

Une explication du code est incluse dans les commentaires :

Dim key As String

Dim table As Word.table

Dim objects As String

Dim connection As New ADODB.connection

Dim recordset As New ADODB.recordset

' Connectez-vous au DSN que nous allons utiliser

connection.Open "DSN=EMu Loans ;"

' Ce code parcourt chaque table ajoutée au document Word afin de la remplir

' avec des données. Dans cet exemple nous n’avons qu’une seule table.

For Each table In ActiveDocument.Tables

 	' Notre table a deux colonnes

 	If table.Columns.Count = 2 Then

	 ' Dans la première cellule d'une table de notre document de publipostage, nous avons inséré

	 ' le champ clé qui associe les différents fichiers .csv (dans notre exemple, eloans_key).

	 ' Nous devons obtenir la valeur de cette clé afin d'interroger le deuxième (troisième, n-ième) fichier .csv.

	 ' Ce code prend la valeur de la clé de la première cellule de la table

	 key = table.Cell(1, 1).Range.Text

	 key = Trim(Left(key, Len(key) - 2))

	 objects = ""

	 ' Ce code interroge le deuxième fichier .csv

	 recordset.Open "select * from ObjObjec.csv where eloans_key = " & key, connection

	 ' Ce code remplit la table de notre rapport de publipostage avec les données

	 ' (du champ Données sommaires de notre second fichier .csv dans cet exemple)

	 ' une ligne pour chaque enregistrement

	 While Not recordset.EOF

 		If objects <> "" Then

			 objects = objects & Chr(10)

		 End If

		 objects = objects & recordset("SummaryData")

		 recordset.MoveNext

	 Wend

	 table.Cell(1, 2).Range.Text = objects

	 recordset.Close

	 ' Ce code supprime ensuite la colonne contenant la eloans_key de notre table de publipostage

	 ' afin qu'elle ne s'affiche pas dans le rapport de publipostage

	 table.Columns(1).Select

	 Selection.Columns.Delete

	 ' Cela supprime les bordures de la table

	 table.Borders.Enable = False

 End If

Next table

' Fermer nos connexions

 connection.Close

Note: Dans cet exemple, nous remplissons la table avec une valeur (Données sommaires) pour chaque objet du fichier .csv associé (un prêt peut concerner un ou plusieurs objets). Ce code va générer une table statique : une table comportant une seule ligne dans laquelle sont répertoriés tous les enregistrements associés, une ligne pour chaque enregistrement d'objet (voir Étape 4 : Lancer le publipostage pour un exemple d'affichage de ce rapport de publipostage).
Si nous voulions afficher deux valeurs pour chaque objet dans le fichier .csv associé (par exemple, NEI et Données sommaires), une table statique pourrait être un mauvais choix, car nous aurions besoin de deux colonnes pour contenir les deux valeurs, mais comme nous n’avons qu’une seule ligne, les valeurs dans les deux colonnes pourraient se désynchroniser. Ce dont nous avons besoin dans ce cas, c'est d'une ligne pour chaque enregistrement associé : cela nécessite du code pour générer une table dynamique.

Sauvegarder et fermer le document de rapport principal.
À 1. Écrire le code VB nous avions modifié le code VB en le commentant dans le but de faire un test MainDocument.Close SaveChanges:=False. Avant de pouvoir finaliser le rapport, nous devons éditer le code VB pour supprimer l'apostrophe.

[Fermer]